docs/card__manager_8gd_source.html

extends RefCounted


const DataCacheManager = preload("res://scripts/systems/dataCacheManager/data_cache_manager.gd")


var cards := {}

var cards_by_rarity := {}

var card_order := []

var data_cache_manager = DataCacheManager.new()


func load_cards(file_path:String) -> void:

    reset()

    load_card_data(data_cache_manager.load_json(file_path))


func get_cache_stats() -> Dictionary:

    return data_cache_manager.get_cache_stats()


func load_card_data(data) -> void:

    reset()

    if not data is Dictionary:

        return

    for raw_card in data.get("cards", []):

        if not raw_card is Dictionary:

            continue

        var card = raw_card.duplicate(true)

        var id = str(card.get("id", ""))

        if id == "":

            continue

        var rarity = str(card.get("rarity", "Common"))

        cards[id] = card

        card_order.append(id)

        if not cards_by_rarity.has(rarity):

            cards_by_rarity[rarity] = []

        cards_by_rarity[rarity].append(card)


func get_card(id) -> Dictionary:

    return cards.get(str(id), {})


func get_all_cards() -> Array:

    var list = []

    for id in card_order:

        list.append(cards[id])

    return list


func get_cards_by_rarity(rarity:String) -> Array:

    return cards_by_rarity.get(rarity, [])


func get_random_card_by_rarity(rarity:String) -> Dictionary:

    var options = get_cards_by_rarity(rarity)

    if options.is_empty():

        return {}

    return options[randi_range(0, options.size() - 1)].duplicate(true)


func get_random_card() -> Dictionary:

    var all_cards = get_all_cards()

    if all_cards.is_empty():

        return {}

    return all_cards[randi_range(0, all_cards.size() - 1)].duplicate(true)


func reset() -> void:

    cards.clear()

    cards_by_rarity.clear()

    card_order.clear()