docs/pack__manager_8gd_source.html

extends RefCounted


const DataCacheManager = preload("res://scripts/systems/dataCacheManager/data_cache_manager.gd")


var packs := {}

var pack_order := []

var data_cache_manager = DataCacheManager.new()


func load_packs(file_path:String) -> void:

    reset()

    load_pack_data(data_cache_manager.load_json(file_path))


func get_cache_stats() -> Dictionary:

    return data_cache_manager.get_cache_stats()


func load_pack_data(data) -> void:

    reset()

    if not data is Dictionary:

        return

    for raw_pack in data.get("packs", []):

        if not raw_pack is Dictionary:

            continue

        var pack = raw_pack.duplicate(true)

        var id = str(pack.get("id", pack.get("name", "")))

        if id == "":

            continue

        pack["id"] = id

        packs[id] = pack

        pack_order.append(id)


func get_pack(id:String) -> Dictionary:

    return packs.get(id, {})


func get_packs() -> Array:

    var list = []

    for id in pack_order:

        list.append(packs[id])

    return list


func open_pack(pack_id:String, card_manager) -> Array:

    var pack = get_pack(pack_id)

    if pack.is_empty():

        return []

    var opened = []

    for i in range(int(pack.get("cards", 5))):

        var rarity = _roll_rarity(pack.get("weights", {}))

        var card = card_manager.get_random_card_by_rarity(rarity)

        if card.is_empty():

            card = card_manager.get_random_card()

        if not card.is_empty():

            opened.append(card)

    return opened


func _roll_rarity(weights:Dictionary) -> String:

    var total = 0

    for rarity in weights.keys():

        total += int(weights[rarity])

    if total <= 0:

        return "Common"

    var roll = randi_range(1, total)

    var running = 0

    for rarity in weights.keys():

        running += int(weights[rarity])

        if roll <= running:

            return str(rarity)

    return str(weights.keys()[0])


func reset() -> void:

    packs.clear()

    pack_order.clear()