build_info.gd

Go to the documentation of this file.

extends RefCounted
 
 
 
const DEFAULT_PATH := "res://data/build_info.json"
const DataCacheManager = preload("res://scripts/systems/dataCacheManager/data_cache_manager.gd")
 
var data:Dictionary = {
    "build_date": "",
    "channel": "local",
    "launch_scene": "res://scenes/start_menu.tscn"
}
var data_cache_manager = DataCacheManager.new()
 
 
 
func load_info(file_path:String = DEFAULT_PATH) -> Dictionary:
    var parsed := data_cache_manager.load_json(file_path)
    for key in parsed.keys():
        data[key] = parsed[key]
    return data.duplicate(true)
 
 
 
func get_label(prefix:String = "Build") -> String:
    var build_date := _resolved_build_date()
    if build_date == "":
        build_date = _runtime_build_date()
    return "%s %s" % [prefix, build_date]
 
 
 
func get_launch_scene(default_scene:String = "res://scenes/start_menu.tscn") -> String:
    var launch_scene := str(data.get("launch_scene", default_scene))
    if launch_scene.strip_edges() == "":
        return default_scene
    return launch_scene
 
 
func get_state() -> Dictionary:
    return data.duplicate(true)
 
 
 
func get_cache_stats() -> Dictionary:
    return data_cache_manager.get_cache_stats()
 
 
func _resolved_build_date() -> String:
    var channel := str(data.get("channel", "local"))
    if channel == "local" or channel.begins_with("local_"):
        return _runtime_build_date()
    return str(data.get("build_date", _runtime_build_date()))
 
 
func _runtime_build_date() -> String:
    var date := Time.get_date_dict_from_system()
    return "%04d%02d%02d" % [int(date.get("year", 0)), int(date.get("month", 0)), int(date.get("day", 0))]