info_panel.gd

Go to the documentation of this file.

extends RefCounted
 
 
 
 
func create_popup(owner:Node, title_text:String, pages:Array, options:Dictionary = {}) -> PopupPanel:
    var popup := PopupPanel.new()
    popup.name = str(options.get("name", "InfoPopup"))
    popup.size = _option_vector2i(options, "size", Vector2i(520, 560))
    if owner != null:
        owner.add_child(popup)
 
    var content := VBoxContainer.new()
    content.name = "Content"
    content.set_anchors_preset(Control.PRESET_FULL_RECT)
    var margin:int = int(options.get("margin", 16))
    content.offset_left = margin
    content.offset_top = margin
    content.offset_right = -margin
    content.offset_bottom = -margin
    content.add_theme_constant_override("separation", int(options.get("separation", 10)))
    popup.add_child(content)
 
    var title := Label.new()
    title.name = "Title"
    title.text = title_text
    title.horizontal_alignment = HORIZONTAL_ALIGNMENT_CENTER
    title.autowrap_mode = TextServer.AUTOWRAP_WORD_SMART
    title.add_theme_font_size_override("font_size", int(options.get("title_font_size", 22)))
    content.add_child(title)
 
    var tabs := TabContainer.new()
    tabs.name = "Tabs"
    tabs.size_flags_horizontal = Control.SIZE_EXPAND_FILL
    tabs.size_flags_vertical = Control.SIZE_EXPAND_FILL
    content.add_child(tabs)
 
    for page_value in pages:
        if page_value is Dictionary:
            tabs.add_child(_create_page(page_value))
 
    var back := Button.new()
    back.name = str(options.get("back_name", "Back"))
    back.text = str(options.get("back_label", "Back"))
    back.custom_minimum_size = Vector2(0, float(options.get("back_height", 48.0)))
    var callback:Callable = options.get("back_callback", Callable())
    back.pressed.connect(func():
        if callback.is_valid():
            callback.call()
        else:
            popup.hide()
    )
    content.add_child(back)
    return popup
 
 
func get_tab_container(popup:PopupPanel) -> TabContainer:
    if popup == null:
        return null
    var tabs = popup.get_node_or_null("Content/Tabs")
    if tabs is TabContainer:
        return tabs
    return null
 
 
func step_tab(popup:PopupPanel, direction:int) -> void:
    var tabs := get_tab_container(popup)
    if tabs == null or tabs.get_tab_count() <= 0:
        return
    tabs.current_tab = wrapi(tabs.current_tab + direction, 0, tabs.get_tab_count())
 
 
func reset_tab(popup:PopupPanel, tab_index:int = 0) -> void:
    var tabs := get_tab_container(popup)
    if tabs == null or tabs.get_tab_count() <= 0:
        return
    tabs.current_tab = clampi(tab_index, 0, tabs.get_tab_count() - 1)
 
 
 
func add_info_card(parent:Container, card:Dictionary, options:Dictionary = {}) -> PanelContainer:
    var panel := PanelContainer.new()
    panel.name = str(card.get("title", "Info")).replace(" ", "") + "InfoCard"
    panel.size_flags_horizontal = Control.SIZE_EXPAND_FILL
    panel.add_theme_stylebox_override("panel", _info_card_style(options))
 
    var margin := MarginContainer.new()
    var padding:int = int(options.get("padding", 14))
    margin.add_theme_constant_override("margin_left", padding)
    margin.add_theme_constant_override("margin_right", padding)
    margin.add_theme_constant_override("margin_top", max(8, padding - 4))
    margin.add_theme_constant_override("margin_bottom", max(8, padding - 4))
    panel.add_child(margin)
 
    var row := HBoxContainer.new()
    row.name = "Body"
    row.add_theme_constant_override("separation", int(options.get("gap", 12)))
    margin.add_child(row)
 
    var icon_label := Label.new()
    icon_label.name = "Icon"
    icon_label.custom_minimum_size = Vector2(float(options.get("icon_width", 38.0)), 0)
    icon_label.text = str(card.get("icon", ""))
    icon_label.horizontal_alignment = HORIZONTAL_ALIGNMENT_CENTER
    icon_label.vertical_alignment = VERTICAL_ALIGNMENT_CENTER
    icon_label.add_theme_font_size_override("font_size", int(options.get("icon_font_size", 22)))
    icon_label.add_theme_color_override("font_color", Color(str(options.get("accent", "#4bb3ff"))))
    row.add_child(icon_label)
 
    var stack := VBoxContainer.new()
    stack.name = "Text"
    stack.size_flags_horizontal = Control.SIZE_EXPAND_FILL
    stack.add_theme_constant_override("separation", int(options.get("text_gap", 2)))
    row.add_child(stack)
 
    var kicker := Label.new()
    kicker.name = "Kicker"
    kicker.text = str(card.get("kicker", ""))
    kicker.autowrap_mode = TextServer.AUTOWRAP_WORD_SMART
    kicker.add_theme_font_size_override("font_size", int(options.get("kicker_font_size", 12)))
    kicker.add_theme_color_override("font_color", Color(str(options.get("accent", "#4bb3ff"))))
    stack.add_child(kicker)
 
    var title := Label.new()
    title.name = "Title"
    title.text = str(card.get("title", "Info"))
    title.autowrap_mode = TextServer.AUTOWRAP_WORD_SMART
    title.max_lines_visible = int(options.get("title_lines", 1))
    title.add_theme_font_size_override("font_size", int(options.get("title_font_size", 20)))
    title.add_theme_color_override("font_color", Color(str(options.get("text", "#eef3f8"))))
    stack.add_child(title)
 
    var body := Label.new()
    body.name = "Description"
    body.text = str(card.get("text", ""))
    body.autowrap_mode = TextServer.AUTOWRAP_WORD_SMART
    body.max_lines_visible = int(options.get("body_lines", 3))
    body.add_theme_font_size_override("font_size", int(options.get("body_font_size", 14)))
    body.add_theme_color_override("font_color", Color(str(options.get("muted", "#aab6c4"))))
    stack.add_child(body)
 
    if parent != null:
        parent.add_child(panel)
    return panel
 
 
func _create_page(page:Dictionary) -> ScrollContainer:
    var scroll := ScrollContainer.new()
    scroll.name = str(page.get("id", page.get("title", "InfoPage"))).replace(" ", "")
    scroll.horizontal_scroll_mode = ScrollContainer.SCROLL_MODE_DISABLED
    scroll.size_flags_horizontal = Control.SIZE_EXPAND_FILL
    scroll.size_flags_vertical = Control.SIZE_EXPAND_FILL
 
    var body := VBoxContainer.new()
    body.name = "Content"
    body.size_flags_horizontal = Control.SIZE_EXPAND_FILL
    body.add_theme_constant_override("separation", int(page.get("separation", 8)))
    scroll.add_child(body)
 
    var title := Label.new()
    title.name = "PageTitle"
    title.text = str(page.get("title", "Info"))
    title.horizontal_alignment = HORIZONTAL_ALIGNMENT_CENTER
    title.autowrap_mode = TextServer.AUTOWRAP_WORD_SMART
    title.add_theme_font_size_override("font_size", int(page.get("title_font_size", 18)))
    body.add_child(title)
 
    var lines:Array = page.get("lines", [])
    for line_value in lines:
        var label := Label.new()
        label.text = str(line_value)
        label.autowrap_mode = TextServer.AUTOWRAP_WORD_SMART
        label.size_flags_horizontal = Control.SIZE_EXPAND_FILL
        body.add_child(label)
    return scroll
 
 
func _info_card_style(options:Dictionary) -> StyleBoxFlat:
    var style := StyleBoxFlat.new()
    var background := Color(str(options.get("background", "#1a222bcc")))
    background.a = clampf(float(options.get("opacity", background.a)), 0.0, 1.0)
    style.bg_color = background
    style.border_color = Color(str(options.get("border", "#33404d")))
    style.set_border_width_all(int(options.get("border_width", 1)))
    style.set_corner_radius_all(int(options.get("radius", 8)))
    return style
 
 
func _option_vector2i(options:Dictionary, key:String, default_value:Vector2i) -> Vector2i:
    if not options.has(key):
        return default_value
    var value = options[key]
    if value is Vector2i:
        return value
    if value is Vector2:
        return Vector2i(int(value.x), int(value.y))
    return default_value