docs/settings__panel__controller_8gd_source.html

extends RefCounted


const SettingsManagerScript = preload("res://scripts/systems/settingsManager/settings_manager.gd")


var controls := {}

var settings_manager_fallback


func bind(bound_controls:Dictionary) -> void:

    controls = bound_controls

    var settings_manager = _settings_manager()

    sync_values()

    controls["window_size"].item_selected.connect(_on_window_size_selected)

    if controls.has("theme"):

        controls["theme"].item_selected.connect(_on_theme_selected)

    if controls.has("text_size"):

        controls["text_size"].item_selected.connect(_on_text_size_selected)

    if controls.has("input_mode"):

        controls["input_mode"].item_selected.connect(_on_input_mode_selected)

    controls["fullscreen"].toggled.connect(settings_manager.set_fullscreen)

    if controls.has("low_power_mode"):

        controls["low_power_mode"].toggled.connect(settings_manager.set_low_power_mode)

    controls["master_slider"].value_changed.connect(func(value): _settings_manager().set_audio_value("master_volume", value / 100.0))

    controls["music_slider"].value_changed.connect(func(value): _settings_manager().set_audio_value("music_volume", value / 100.0))

    controls["sfx_slider"].value_changed.connect(func(value): _settings_manager().set_audio_value("sfx_volume", value / 100.0))

    controls["master_mute"].toggled.connect(func(value): _settings_manager().set_audio_value("master_muted", value))

    controls["music_mute"].toggled.connect(func(value): _settings_manager().set_audio_value("music_muted", value))

    controls["sfx_mute"].toggled.connect(func(value): _settings_manager().set_audio_value("sfx_muted", value))


func sync_values() -> void:

    var settings_manager = _settings_manager()

    var settings = settings_manager.get_settings()

    var window_size_options = settings_manager.get_window_size_options()

    controls["window_size"].clear()

    var selected_index = 0

    var index = 0

    for label in window_size_options.keys():

        controls["window_size"].add_item(label)

        if window_size_options[label] == settings["window_size"]:

            selected_index = index

        index += 1

    controls["window_size"].select(selected_index)

    if controls.has("theme"):

        controls["theme"].clear()

        var theme_options = settings_manager.get_theme_options()

        var selected_theme_index = 0

        var theme_index = 0

        for label in theme_options.keys():

            controls["theme"].add_item(label)

            if theme_options[label] == settings["theme"]:

                selected_theme_index = theme_index

            theme_index += 1

        controls["theme"].select(selected_theme_index)

    if controls.has("text_size"):

        controls["text_size"].clear()

        var text_size_options = settings_manager.get_text_size_options()

        var selected_text_index = 0

        var text_index = 0

        for label in text_size_options.keys():

            controls["text_size"].add_item(label)

            if text_size_options[label] == settings["text_size"]:

                selected_text_index = text_index

            text_index += 1

        controls["text_size"].select(selected_text_index)

    if controls.has("input_mode"):

        controls["input_mode"].clear()

        var input_mode_options = settings_manager.get_input_mode_options()

        var selected_input_index := 0

        var input_index := 0

        for label in input_mode_options.keys():

            controls["input_mode"].add_item(label)

            if input_mode_options[label] == settings.get("input_mode", "touch"):

                selected_input_index = input_index

            input_index += 1

        controls["input_mode"].select(selected_input_index)

    controls["fullscreen"].button_pressed = bool(settings["fullscreen"])

    if controls.has("low_power_mode"):

        controls["low_power_mode"].button_pressed = bool(settings.get("low_power_mode", false))

    controls["master_slider"].value = float(settings["master_volume"]) * 100.0

    controls["music_slider"].value = float(settings["music_volume"]) * 100.0

    controls["sfx_slider"].value = float(settings["sfx_volume"]) * 100.0

    controls["master_mute"].button_pressed = bool(settings["master_muted"])

    controls["music_mute"].button_pressed = bool(settings["music_muted"])

    controls["sfx_mute"].button_pressed = bool(settings["sfx_muted"])


func _on_window_size_selected(index:int) -> void:

    var label = controls["window_size"].get_item_text(index)

    _settings_manager().set_window_size_by_label(label)


func _on_theme_selected(index:int) -> void:

    var label = controls["theme"].get_item_text(index)

    _settings_manager().set_theme_by_label(label)


func _on_text_size_selected(index:int) -> void:

    var label = controls["text_size"].get_item_text(index)

    _settings_manager().set_text_size_by_label(label)


func _on_input_mode_selected(index:int) -> void:

    var label = controls["input_mode"].get_item_text(index)

    var options = _settings_manager().get_input_mode_options()

    _settings_manager().set_input_mode(str(options.get(label, "touch")))


func _settings_manager():

    var manager = _get_autoload("SettingsManager")

    if manager != null:

        return manager

    if settings_manager_fallback == null:

        settings_manager_fallback = SettingsManagerScript.new()

    return settings_manager_fallback


func _get_autoload(name:String):

    var loop = Engine.get_main_loop()

    if loop is SceneTree:

        return loop.root.get_node_or_null(name)

    return null