sprite_animation_rect.gd

Go to the documentation of this file.

extends TextureRect
 
 
 
var frames := []
var fps := 8.0
var loop := true
var playing := true
var elapsed := 0.0
var current_frame := -1
 
 
 
func configure(next_frames:Array, options:Dictionary = {}) -> void:
    frames = next_frames.duplicate()
    fps = max(0.1, float(options.get("fps", 8.0)))
    loop = bool(options.get("loop", true))
    playing = bool(options.get("autoplay", true))
    elapsed = float(options.get("offset_seconds", 0.0))
    stretch_mode = TextureRect.STRETCH_KEEP_ASPECT_CENTERED
    expand_mode = TextureRect.EXPAND_IGNORE_SIZE
    mouse_filter = Control.MOUSE_FILTER_IGNORE
    _update_frame()
 
 
func play() -> void:
    playing = true
 
 
func stop() -> void:
    playing = false
 
 
func _process(delta:float) -> void:
    if not playing or frames.size() <= 1:
        return
    elapsed += delta
    _update_frame()
 
 
func _update_frame() -> void:
    if frames.is_empty():
        texture = null
        current_frame = -1
        return
    var frame = int(floor(elapsed * fps))
    if loop:
        frame = frame % frames.size()
    else:
        frame = min(frame, frames.size() - 1)
    if frame == current_frame:
        return
    current_frame = frame
    texture = frames[current_frame]