ui_flow_manager.gd

Go to the documentation of this file.

extends RefCounted
 
 
 
 
 
func focus_first(root:Node) -> Control:
    var control = find_first_focusable(root)
    if control != null and control.is_inside_tree():
        control.grab_focus()
    return control
 
 
 
func focus_named(root:Node, node_name:String, fallback_to_first:bool = true) -> Control:
    if root == null:
        return null
    var target = root.find_child(node_name, true, false)
    if target is Control and target.visible and target.focus_mode != Control.FOCUS_NONE:
        if not (target is BaseButton) or not target.disabled:
            if target.is_inside_tree():
                target.grab_focus()
            return target
    return focus_first(root) if fallback_to_first else null
 
 
 
func focus_button_by_text(root:Node, labels:Array, fallback_to_first:bool = true) -> Control:
    if root == null:
        return null
    var target = _find_button_by_text(root, labels)
    if target != null:
        if target.is_inside_tree():
            target.grab_focus()
        return target
    return focus_first(root) if fallback_to_first else null
 
 
 
func focus_first_on_navigation(root:Node, event:InputEvent) -> bool:
    if root == null or event == null:
        return false
    if not _is_navigation_event(event):
        return false
    var viewport = root.get_viewport() if root is Control else null
    if viewport != null and viewport.gui_get_focus_owner() != null:
        return false
    return focus_first(root) != null
 
 
 
func find_first_focusable(root:Node) -> Control:
    if root == null:
        return null
    for child in root.get_children():
        if child is Control and child.visible and child.focus_mode != Control.FOCUS_NONE:
            if not (child is BaseButton) or not child.disabled:
                return child
        var nested = find_first_focusable(child)
        if nested != null:
            return nested
    return null
 
 
 
func set_focus_mode_recursive(root:Node, mode:int) -> void:
    if root == null:
        return
    if root is Control:
        root.focus_mode = mode
    for child in root.get_children():
        set_focus_mode_recursive(child, mode)
 
 
 
func show_screen(screen_id:String, screens:Dictionary, scroll:ScrollContainer = null) -> String:
    for id in screens.keys():
        var screen = screens[id]
        if screen is Control:
            screen.visible = str(id) == screen_id
    if scroll != null:
        call_deferred("_set_scroll_vertical_if_valid", scroll, 0)
    return screen_id
 
 
 
func shifted_id(current_id:String, ordered_ids:Array, delta:int) -> String:
    if ordered_ids.is_empty():
        return current_id
    var index = ordered_ids.find(current_id)
    if index < 0:
        index = 0
    return str(ordered_ids[posmod(index + delta, ordered_ids.size())])
 
 
 
func visible_screen_id(screens:Dictionary, fallback:String = "") -> String:
    for id in screens.keys():
        var screen = screens[id]
        if screen is Control and screen.visible:
            return str(id)
    return fallback
 
 
 
func format_local_time(unix_time:float) -> String:
    if unix_time <= 0.0:
        return "Unknown"
    var value = Time.get_datetime_string_from_unix_time(int(unix_time), true)
    return value.replace("T", " ").substr(0, 16)
 
 
 
func set_label_text_if_changed(label:Label, text:String) -> bool:
    if label == null:
        return false
    if label.text == text:
        return false
    label.text = text
    return true
 
 
func _is_navigation_event(event:InputEvent) -> bool:
    for action in ["ui_up", "ui_down", "ui_left", "ui_right"]:
        if event.is_action_pressed(action):
            return true
    return false
 
 
func _find_button_by_text(root:Node, labels:Array) -> Control:
    for child in root.get_children():
        if child is Button and child.visible and not child.disabled and labels.has(str(child.text)):
            return child
        var nested = _find_button_by_text(child, labels)
        if nested != null:
            return nested
    return null
 
 
func _set_scroll_vertical_if_valid(scroll:ScrollContainer, value:int) -> void:
    if scroll != null and is_instance_valid(scroll):
        scroll.scroll_vertical = value