data_cache_manager.gd

Go to the documentation of this file.

extends RefCounted
 
 
 
var json_cache:Dictionary = {}
var cache_hits:int = 0
var cache_misses:int = 0
 
 
 
func load_json(path:String) -> Dictionary:
    var parsed = load_data(path)
    if parsed is Dictionary:
        return parsed
    return {}
 
 
 
func load_data(path:String):
    if path == "":
        return {}
    if json_cache.has(path):
        cache_hits += 1
        return _duplicate_cached(json_cache[path])
    cache_misses += 1
    var file := FileAccess.open(path, FileAccess.READ)
    if file == null:
        json_cache[path] = {}
        return {}
    var parsed = JSON.parse_string(file.get_as_text())
    if not parsed is Dictionary and not parsed is Array:
        json_cache[path] = {}
        return {}
    json_cache[path] = parsed.duplicate(true)
    return _duplicate_cached(json_cache[path])
 
 
 
func load_array(path:String, key:String, fallback:Array = []) -> Array:
    var data := load_json(path)
    if data.has(key) and data[key] is Array:
        return data[key].duplicate(true)
    return fallback.duplicate(true)
 
 
 
func load_root_array(path:String, fallback:Array = []) -> Array:
    var data = load_data(path)
    if data is Array:
        return data.duplicate(true)
    return fallback.duplicate(true)
 
 
 
func invalidate(path:String) -> void:
    json_cache.erase(path)
 
 
 
func clear() -> void:
    json_cache.clear()
    cache_hits = 0
    cache_misses = 0
 
 
 
func get_cache_state() -> Dictionary:
    return {
        "entries": json_cache.size(),
        "paths": json_cache.keys(),
        "cache_hits": cache_hits,
        "cache_misses": cache_misses
    }
 
 
 
func get_cache_stats() -> Dictionary:
    return {
        "entries": json_cache.size(),
        "cache_hits": cache_hits,
        "cache_misses": cache_misses
    }
 
 
func _duplicate_cached(value):
    if value is Dictionary or value is Array:
        return value.duplicate(true)
    return value