resource_manager.gd

Go to the documentation of this file.

 
 
const DataCacheManager = preload("res://scripts/systems/dataCacheManager/data_cache_manager.gd")
 
var resources = {}
var resource_definitions = {}
var resource_order = []
var data_cache = DataCacheManager.new()
 
var hud = preload("res://scripts/systems/resourceManager/resource_hud.gd").new()
 
func _init(resource_hud):
    hud.resource_hud = resource_hud
 
 
 
func set_sprite_manager(sprite_manager) -> void:
    hud.sprite_manager = sprite_manager
 
 
func check_game_over():
    for id in resource_order:
        if int(resources.get(id, 0)) <= 0:
            return true
    return false
 
func get_symbol(id:String) -> String:
    var def: Dictionary = resource_definitions.get(id.to_lower(), {})
    
    return def.get("icon", id.capitalize())
 
func get_icon_path(id:String) -> String:
    var def: Dictionary = resource_definitions.get(id.to_lower(), {})
    return str(def.get("icon_path", ""))
 
func get_sprite_id(id:String) -> String:
    var def: Dictionary = resource_definitions.get(id.to_lower(), {})
    return str(def.get("sprite_id", ""))
 
 
func get_value(id:String, default_value:int = 100) -> int:
    return int(resources.get(id, default_value))
 
func get_min_value(id:String) -> int:
    var def: Dictionary = resource_definitions.get(id, {})
    return int(def.get("min_value", 0))
 
func get_max_value(id:String) -> int:
    var def: Dictionary = resource_definitions.get(id, {})
    return int(def.get("max_value", 100))
 
func get_impact_marks(amount:int) -> String:
    var count = 1
    var absolute_amount = abs(amount)
    if absolute_amount >= 15:
        count = 3
    elif absolute_amount >= 8:
        count = 2
    var mark = "+" if amount > 0 else "-"
    return mark.repeat(count)
 
func format_choice_effects(choice:Dictionary) -> String:
    var parts = []
    for effect in choice.get("effects", []):
        var id = str(effect.get("resource", ""))
        var amount = int(effect.get("amount", 0))
        if id == "" or amount == 0:
            continue
        parts.append(get_symbol(id) + " " + get_impact_marks(amount))
    if parts.is_empty():
        return ""
    return "\n" + "   ".join(parts)
 
func get_resource_order() -> Array:
    return resource_order.duplicate()
 
 
func get_effect_indicators(effects:Array, ordered:bool = true) -> Array:
    var indicators = []
    var sorted_effects = _sort_effects_by_resource_order(effects) if ordered else effects
    for effect in sorted_effects:
        var id = str(effect.get("resource", ""))
        var amount = int(effect.get("amount", 0))
        if id == "" or amount == 0:
            continue
        indicators.append({
            "resource": id,
            "amount": amount,
            "icon": get_symbol(id),
            "sprite_id": get_sprite_id(id),
            "icon_path": get_icon_path(id),
            "marks": get_impact_marks(amount)
        })
    return indicators
 
func _sort_effects_by_resource_order(effects:Array) -> Array:
    var sorted_effects = []
    for resource_id in resource_order:
        for effect in effects:
            if str(effect.get("resource", "")) == resource_id:
                sorted_effects.append(effect)
    for effect in effects:
        var id = str(effect.get("resource", ""))
        if id != "" and not resource_order.has(id):
            sorted_effects.append(effect)
    return sorted_effects
 
 
func apply_effects(effects:Array) -> void:
    for effect in effects:
        var id = str(effect.get("resource", ""))
        if resources.has(id):
            resources[id] = clampi(resources[id] + int(effect.get("amount", 0)), get_min_value(id), get_max_value(id))
 
 
func can_apply_effects(effects:Array) -> bool:
    for effect in effects:
        var id = str(effect.get("resource", ""))
        var amount = int(effect.get("amount", 0))
        if resources.has(id) and get_value(id) + amount < get_min_value(id):
            return false
    return true
 
func set_value(id:String, value:int) -> void:
    if resources.has(id):
        resources[id] = clampi(value, get_min_value(id), get_max_value(id))
 
 
func get_state() -> Dictionary:
    return resources.duplicate(true)
 
 
func apply_state(saved_resources:Dictionary) -> void:
    for id in saved_resources.keys():
        set_value(str(id), int(saved_resources[id]))
 
 
func load(resource_file_path:String = "res://data/games/reflecting_pool/resources.json"):
    load_resource_data(data_cache.load_json(resource_file_path))
 
 
 
func load_resource_data(data:Dictionary) -> void:
    reset()
    for r in data.get("resources", []):
        var id = str(r.get("id", ""))
        if id == "":
            continue
        resource_order.append(id)
        resource_definitions[id] = r
        resources[id] = clampi(int(r.get("starting_value", 100)), get_min_value(id), get_max_value(id))
 
func refresh_hud(resource_hud):
    hud.refresh_hud(resources, resource_hud, resource_order, resource_definitions)
 
func apply_hud_text_style(resource_hud) -> void:
    hud.apply_compact_text_style(resource_hud)
 
func clear_hud_selection(resource_hud) -> void:
    hud.clear_selection(resources, resource_hud, resource_order, resource_definitions)
 
func reset():
    resources.clear()
    resource_definitions.clear()
    resource_order.clear()
 
 
func get_cache_stats() -> Dictionary:
    return data_cache.get_cache_stats()